RCWL-1670 Waterproof Ultrasonic Sensor: Full Guide with Arduino Projects & Comparisons

				
					#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define Trig 9    // Connect to RX pin of ultrasonic sensor
#define Echo 10   // Connect to TX pin of ultrasonic sensor
#define buzzer 8  // Buzzer connected to digital pin 8

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

// Water level threshold (unit: percentage)
float lowLevelThreshold = 10.0;  // Alarm when water level is below 10%
int cupHeight = 20;  // Total height of the cup (unit: cm)

// Minimum measurement distance (unit: cm)
float minDistance = 1.0;  // Minimum effective distance to avoid measurement errors when close

// Parameters for average filtering
const int sampleCount = 30;  // Number of sampling times
long durationSum = 0;  // Accumulated echo time
float distance = 0;  // Current distance to water surface

void setup() {
  Serial.begin(9600);
  pinMode(Trig, OUTPUT);
  pinMode(Echo, INPUT);
  pinMode(buzzer, OUTPUT);  // Set buzzer to output mode

  // OLED initialization
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("OLED initialization failed!"));
    while (true);
  }

  display.clearDisplay();
  display.setTextSize(1);          // Font size
  display.setTextColor(SSD1306_WHITE);  // Font color
  display.setCursor(0, 0);        // Set cursor position
  display.println("Water Level Monitoring");
  display.display();
}

void loop() {
  // Accumulate multiple sampling data and calculate average
  durationSum = 0;
  for (int i = 0; i < sampleCount; i++) {
    // Trigger ultrasonic pulse
    digitalWrite(Trig, LOW);
    delayMicroseconds(2);
    digitalWrite(Trig, HIGH);
    delayMicroseconds(10);
    digitalWrite(Trig, LOW);

    // Read echo time
    long duration = pulseIn(Echo, HIGH);
    durationSum += duration;  // Accumulate echo time each time
    delay(10);  // Short delay to avoid reading too fast
  }

  // Calculate average echo time
  long averageDuration = durationSum / sampleCount;
  distance = averageDuration * 0.0343 / 2;  // Calculate distance in cm

  // Ensure distance value is not less than minimum effective distance
  if (distance < minDistance) {
    distance = minDistance;  // Force set to minimum value if distance is too small
  }

  // Output to serial port
  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println(" cm");

  // Calculate current water level percentage
  float waterLevel = (cupHeight - distance) / cupHeight * 100;
  if (waterLevel < 0) waterLevel = 0;  // Prevent negative values

  // Display water level distance and percentage on OLED
  display.clearDisplay();
  display.setTextSize(2);         // Set larger font size
  display.setCursor(0, 20);
  display.print("Distance: ");
  display.print(distance);
  display.println(" cm");

  display.setTextSize(1);         // Set smaller font size
  display.setCursor(0, 50);
  display.print("Water Level: ");
  display.print(waterLevel, 1);   // Display water level percentage with 1 decimal place
  display.print("%");
  display.display();

  // Alarm if water level is below 10%
  if (waterLevel < lowLevelThreshold) {
    digitalWrite(buzzer, LOW);  // Turn on buzzer
  } else {
    digitalWrite(buzzer, HIGH);   // Turn off buzzer
  }

  delay(200);  // Short delay to avoid too frequent loops
}