The Ultimate Guide to TTP229 Capacitive Touch Sensor Module

				
					#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
#define SCREEN_ADDRESS 0x3C

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

#define SCL 8
#define SDO 9
byte Key;
String inputString = "";
float result = 0;
boolean newCalculation = true;

const char keyMap[16] = {
  '1', '2', '3', 'C',    // Clear-->'C'
  '4', '5', '6', '/', 
  '7', '8', '9', '*',
  '0', '=', '+', '-'
};

byte Read_TTP229_Keypad(void)
{
  byte Num;
  byte Key_State = 0;
  for(Num = 1; Num <= 16; Num++)
  {
    digitalWrite(SCL, LOW);
    delayMicroseconds(10);
    if (!digitalRead(SDO))
      Key_State = Num;
    digitalWrite(SCL, HIGH);
    delayMicroseconds(10);
  } 
  return Key_State;
}

void displayCalculator() {
  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  
  // Show the complete formula (in large font)
  display.setTextSize(2);
  display.setCursor(0, 5);
  
  if (inputString.length() > 0) {
    display.print(inputString);
  } else {
    display.print("0");
  }
  
  // Display the equal sign and the result
  if (!newCalculation || result != 0) {
    display.setCursor(0, 30);
    display.setTextSize(2);
    display.print("= ");
    
    if (result == floor(result)) {
      display.print((long)result);
    } else {
      display.print(result, 2);
    }
  }
  
  display.display();
}

void calculateResult() {
  if (inputString.length() == 0) return;
  
  float num1 = 0, num2 = 0;
  char op = ' ';
  int operatorPos = -1;
  
  // Find the position of the operator
  for (int i = inputString.length()-1; i >= 0; i--) {
    if (inputString[i] == '+' || inputString[i] == '-' || 
        inputString[i] == '*' || inputString[i] == '/') {
      operatorPos = i;
      op = inputString[i];
      break;
    }
  }
  
  if (operatorPos == -1) {
    result = inputString.toFloat();
    return;
  }
  
  // Extract operand
  String str1 = inputString.substring(0, operatorPos);
  String str2 = inputString.substring(operatorPos + 1);
  
  num1 = str1.toFloat();
  num2 = str2.toFloat();
  
  // Perform the operation
  switch(op) {
    case '+':
      result = num1 + num2;
      break;
    case '-':
      result = num1 - num2;
      break;
    case '*':
      result = num1 * num2;
      break;
    case '/':
      if (num2 != 0) {
        result = num1 / num2;
      } else {
        inputString = "Error";
        result = 0;
        return;
      }
      break;
  }
  
  // Maintain an appropriate level of precision
  if (result != floor(result)) {
    result = round(result * 100) / 100;
  }
}

void setup()
{
  Serial.begin(9600);
  
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0,0);
  display.println("Calc Ready");
  display.display();
  delay(1500);
  
  pinMode(SCL, OUTPUT); 
  pinMode(SDO, INPUT);
  digitalWrite(SCL, HIGH);
}

void loop()
{
  Key = Read_TTP229_Keypad();
  
  if (Key)
  {
    char pressedKey = keyMap[Key-1];  // Key starts from 1, and the array index starts from 0.
    
    Serial.print("Key: ");
    Serial.println(pressedKey);
    
    switch(pressedKey) {
      case 'C':
        // Clear -> Clear everything
        inputString = "";
        result = 0;
        newCalculation = true;
        Serial.println("Cleared");
        break;
        
      case '=':
        if (inputString.length() > 0) {
          calculateResult();
          newCalculation = false;
        }
        break;
        
      case '+':
      case '-':
      case '*':
      case '/':
        if (inputString.length() > 0) {
          char lastChar = inputString.charAt(inputString.length()-1);
          if (isdigit(lastChar) || lastChar == '.') {
            inputString += pressedKey;
          } else if (ispunct(lastChar)) {
            // Replace the last operator
            inputString.setCharAt(inputString.length()-1, pressedKey);
          }
        }
        break;
        
      case '.':
        if (inputString.length() > 0) {
          // Check if there is a decimal point in the current number field
          int startPos = inputString.length() - 1;
          while (startPos >= 0 && (isdigit(inputString.charAt(startPos)) || inputString.charAt(startPos) == '.')) {
            startPos--;
          }
          
          // After locating the starting position of the current number field, check if there is already a decimal point.
          String currentSegment = inputString.substring(startPos + 1);
          if (currentSegment.indexOf('.') == -1) {
            // If there is no decimal point and the last character is an operator, add 0 first.
            char lastChar = inputString.charAt(inputString.length()-1);
            if (ispunct(lastChar)) {
              inputString += '0';
            }
            inputString += pressedKey;
          }
        } else {
          inputString = "0.";
        }
        break;
        
      default:
        // number key
        if (isdigit(pressedKey)) {
          if (newCalculation) {
            inputString = pressedKey;
            newCalculation = false;
          } else {
            inputString += pressedKey;
          }
        }
        break;
    }
    
    // Limit the input length to prevent overflow.
    if (inputString.length() > 12) {
      inputString = inputString.substring(inputString.length() - 12);
    }
    
    displayCalculator();
    delay(200);
  }
  
  delay(50);
}