An Article Guide on the GY-68 BMP180 Sensor

				
					#include <Wire.h>
#include <Adafruit_BMP085.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
Adafruit_BMP085 bmp;

void setup() {
  Serial.begin(9600);
  
  // Initialize OLED (try two common addresses)
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { // Try 0x3C
    Serial.println(F("OLED init failed, trying 0x3D..."));
    if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3D)) { // Try 0x3D
      Serial.println(F("SSD1306 allocation failed"));
      while(1); 
    }
  }
  
  // Initialize BMP180
  if (!bmp.begin()) {
    Serial.println("BMP180 not found");
    while (1);
  }
  
  // Display initialization information
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0,0);
  display.println("Initializing...");
  display.display();
  delay(1000);
}

void loop() {
  // Read sensor data
  float temp = bmp.readTemperature();
  float pressure = bmp.readPressure() / 100.0F;
  float altitude = bmp.readAltitude();

  // Clear the screen and display the data
  display.clearDisplay();
  
  // headline
  display.setTextSize(1);
  display.setCursor(0,0);
  display.println("BMP180 Sensor Data");
  display.drawLine(0, 10, 128, 10, WHITE);
  
  // temperature
  display.setCursor(0,15);
  display.print("Temp: ");
  display.print(temp, 1); // Display one decimal place
  display.println(" C");
  
  // air pressure
  display.setCursor(0,30);
  display.print("Press: ");
  display.print(pressure, 0); // Display integer
  display.println(" hPa");
  
  // altitude
  display.setCursor(0,45);
  display.print("Alt: ");
  display.print(altitude, 1);
  display.println(" m");
  
  display.display();

  // Serial port output
  Serial.print("Temperature: "); Serial.print(temp); Serial.println(" C");
  Serial.print("Pressure: "); Serial.print(pressure); Serial.println(" hPa");
  Serial.print("Altitude: "); Serial.print(altitude); Serial.println(" m");
  Serial.println();
  
  delay(2000); // Update every 2 seconds
}